任意长度的乘法程序(ASM) [转]

cpubbs

<>M_0 EQU 20H ;低位在低地址 被乘数
N_0 EQU 30H ;M_0+5 ;低位在低地址 乘数
X_0 EQU 40H ;N_0+5 ;低位在低地址 积



;现在的程序检查完了，没有问题。
;傲气雄鹰2002.3.31
;-------------------------------
;入口：MMULD ;任意长度的乘法程序。
;堆栈深度：进入MMULD后还需要6个字节深度。其中保存特殊寄存
;器3个，保存B用了1个，调用AADDC_A用了2个，一共用了
;6个字节。
;影响：该程序影响R0-R6所有的寄存器的值。
LEN EQU 05H ;被乘长度，现在的长度=5，可以定义为任意长度。
LEN_ EQU 05H ;乘数长度，现在的长度=5，可以定义为任意长度。
;-------------------------------
MMULD: PUSH PSW
PUSH ACC
PUSH B

MOV A,#LEN ;将结果清空。
ADD A,#LEN_
MOV R1,A
MOV R0,#X_0
MMULD_1:MOV @R0,#00H
INC R0
DJNZ R1,MMULD_1

MOV R2,#00H
MOV R3,#00H
MOV R0,#M_0 ;被乘数
MOV R1,#N_0 ;乘数
MMULD_LOOP_1:
MOV A,@R0
MOV B,@R1
MUL AB
PUSH B
LCALL AADDC_A ;保存到低位
POP B
LCALL AADDC_B ;保存到高位
INC R0
INC R2
CJNE R2,#LEN,MMULD_LOOP_1 ;被乘长度
MOV R0,#M_0
MOV R2,#00H
INC R1
INC R3
CJNE R3,#LEN_,MMULD_LOOP_1 ;乘数长度
POP B
POP ACC
POP PSW
RET
;将ACC加入到结果中。地址为X_0+R2+R3
AADDC_A:
MOV R6,A ;DATA SAVE TO R6。 ;加数在R6中
MOV A,R0
MOV R4,A ;R0   SAVE TO R4
MOV A,#X_0
ADD A,R2
ADD A,R3
MOV R0,A ;被加数放入[R0]
MOV A,#LEN
MOV B,#LEN_
ADD A,B
CLR C
SUBB A,R2
CLR C
SUBB A,R3
MOV R5,A ;长度在R5中
LJMP AADDC
AADDC_B:MOV R6,B ;DATA SAVE TO R6。 ;加数在R6中
MOV A,R0
MOV R4,A ;R0   SAVE TO R4
MOV A,#X_0
ADD A,R2
ADD A,R3
INC A
MOV R0,A ;被加数放入[R0]
MOV A,#LEN
MOV B,#LEN_
ADD A,B
CLR C
SUBB A,R2
CLR C
SUBB A,R3
MOV R5,A ;长度在R5中
LJMP AADDC
AADDC: CLR C ;入口条件:字节数在R5中 ;被加数在[R0]中
;加数在R6中
AADDC_1:MOV A,@R0 ;出口信息:和在[R0]中
ADDC A,R6 ;按字节相加
MOV @R0,A ;和存回[R0]中
MOV R6,#00H
INC R0
DJNZ R5,AADDC_1 ;处理完所有字节
MOV A,R4
MOV R0,A
RET
;-----------------------------------------------------</P>